[Getdp] "Jacobian method error"

[michael.asam at infineon.com]

Hi Ali,

the problem is that the line for defining data_qnb is extremely long (up to column 3337).
This seems to be too much for the parser which makes nonsense then, i.e. includes your
heat.pro twice. Therefore it would be better to store your table in a file and read it with
the command ListFromFile.
Here you can find an example:
https://geuz.org/trac/getdp/wiki/UsageOfTables
(login name: getdp -- password: getdp)

Cheers,
Michael


From: getdp [mailto:getdp-bounces at ace20.montefiore.ulg.ac.be] On Behalf Of Ali Masoudi
Sent: Monday, September 14, 2015 7:02 PM
To: getdp at geuz.org
Subject: [Getdp] "Jacobian method error"

Hi everyone,
I am trying to solve a 3D heat conduction problem . when I open my *.pro file I get an error :"Redefinition of JacobianMethod" .
Here is my heat.pro<http://heat.pro/> file which is included in another 3D.pro file :


DefineConstant[ Flag_AnalysisType = 0 ];

Jacobian {
  { Name JVol ;
    Case {
      { Region All ; Jacobian Vol ; }
    }
  }
  { Name JSur ;
    Case {
      { Region All ; Jacobian Sur ; }
    }
  }
}

Integration {
  { Name I1 ;
    Case {
      { Type Gauss ;
        Case {
              { GeoElement Point       ; NumberOfPoints  1 ; }
              { GeoElement Line        ; NumberOfPoints  3 ; }
              { GeoElement Triangle    ; NumberOfPoints  4 ; }
              { GeoElement Quadrangle  ; NumberOfPoints  4 ; }
              { GeoElement Tetrahedron ; NumberOfPoints  4 ; }
              { GeoElement Hexahedron  ; NumberOfPoints  6 ; }
              { GeoElement Prism       ; NumberOfPoints  6 ; }
            }
      }
    }
  }
}

FunctionSpace {
  { Name Hgrad_T; Type Form0;
    BasisFunction {
      { Name sn; NameOfCoef Tn; Function BF_Node; Support Tot_The;
        Entity NodesOf[All]; }
    }
    Constraint {
      { NameOfCoef Tn; EntityType NodesOf ; NameOfConstraint Temperature; }
    }
  }

}

Function{
  DefineFunction[Flux,qVol,h,hr,TConv];
}
Group{
  DefineGroup[SurConv_The,SurRad_The];
}

Formulation {

  { Name The_T ; Type FemEquation;
    Quantity {
      { Name T;  Type Local; NameOfSpace Hgrad_T; }
    }
    Equation {
      Galerkin { [ k[] * Dof{d T} , {d T} ];
                 In Vol_The; Integration I1; Jacobian JVol;  }

      Galerkin { DtDof [ rhoc[] * Dof{T} , {T} ];
                 In Vol_The; Integration I1; Jacobian JVol;  }

      Galerkin { [ -qVol[] , {T} ];
                 In Vol_The; Integration I1; Jacobian JVol;  }

      Galerkin { [ -Flux[] , {T} ]; // - sign for incoming flux
                 In Sur_The; Integration I1; Jacobian JSur;  }

      Galerkin { [ h[] * Dof{T} , {T} ] ;
                 In SurConv_The ; Integration I1; Jacobian JSur;  }

      Galerkin { [ -h[] * TConv[] , {T} ] ;
                 In SurConv_The ; Integration I1; Jacobian JSur;  }

      Galerkin { [ hr[{T}] * (({T}+273.)^4-(TConv[]+273.)^4) , {T} ] ;
                 In SurRad_The ; Integration I1; Jacobian JSur;  }
    }
  }

}

Resolution {
  { Name analysis;
    System {
      { Name T; NameOfFormulation The_T; }
    }
    Operation {
      If(Flag_AnalysisType == 0) // steady state
        Generate[T] ; Solve T ; SaveSolution T;
      EndIf
      If(Flag_AnalysisType == 1) // transient general
        InitSolution[T] ; SaveSolution[T] ;
        TimeLoopTheta [t0, t1, dt, 1.0] {
          Generate[T] ; Solve[T];
          Test[SaveFct[]] {
            SaveSolution[T];
          }
        }
      EndIf
      If(Flag_AnalysisType == 2) // transient linear fast
        InitSolution[T] ;  SaveSolution[T] ;
        GenerateSeparate[T] ;
        TimeLoopTheta [t0, t1, dt, 1.0] {
              Update[T, TimeFct[]] ;
          SolveAgain[T] ;
              Test[SaveFct[]] {
            SaveSolution[T];
          }
            }
      EndIf
    }
  }
}


PostProcessing {
  { Name The; NameOfFormulation The_T;
    Quantity {
      { Name T; Value{ Local{ [ {T} ] ; In Vol_The; Jacobian JVol; } } }
    }
  }

}


I have also attached all of my files.

--
Ali Masoudi, PhD Candidate
University of Houston
Department of Mechanical Engineering
[Das Bild wurde vom Absender entfernt.]
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://www.geuz.org/pipermail/getdp/attachments/20150915/d5efc80d/attachment-0001.html>
-------------- next part --------------
A non-text attachment was scrubbed...
Name: ~WRD000.jpg
Type: image/jpeg
Size: 823 bytes
Desc: ~WRD000.jpg
URL: <http://www.geuz.org/pipermail/getdp/attachments/20150915/d5efc80d/attachment-0001.jpg>