[Gmsh] Define anchor points or lines.

[Christophe Geuzaine]

Billy Araujo wrote:
> Imagine I have a simple rectangular plane.
> 
> Is it possible to define an anchor point, for example, at the center
> so that the meshing creates a node at that point? How about
> unconnected lines?
> 
> I know this can be done dividing the rectangle into 4 smaller ones but
> that is not what I was looking for.
> 

Hi Billy - Yes, here's an example:

ch_length = 0.4 ;

p1 = newp; Point(p1) = {0, 0, 0, ch_length} ;
p2 = newp; Point(p2) = {2, 0, 0, ch_length} ;
p3 = newp; Point(p3) = {2, 5, 0, ch_length} ;
p4 = newp; Point(p4) = {0, 5, 0, ch_length} ;
p5 = newp; Point(p5) = {0.5, 2, 0, ch_length} ;
p6 = newp; Point(p6) = {1, 1.6, 0, ch_length} ;
p7 = newp; Point(p7) = {1.2, 2.6, 0, ch_length} ;

l1 = newl; Line(l1) = {p1, p2} ;
l2 = newl; Line(l2) = {p2, p3} ;
l3 = newl; Line(l3) = {p3, p4} ;
l4 = newl; Line(l4) = {p4, p1} ;
l5 = newl; Line(l5) = {p6, p7} ;

ll1 = newll; Line Loop (ll1) = {l1, l2, l3, l4} ;
s1 = news; Plane Surface (s1) = {ll1} ;

Point{p5} In Surface{s1} ;
Line{l5} In Surface{s1} ;


(Note that embedding lines is only supported by the MeshAdapt algorithm.)



> Thanks in advance,
> 
> Billy.
> 
> _______________________________________________
> gmsh mailing list
> gmsh at geuz.org
> http://www.geuz.org/mailman/listinfo/gmsh
> 
> 


-- 
Prof. Christophe Geuzaine
University of Liege, Electrical Engineering and Computer Science
http://www.montefiore.ulg.ac.be/~geuzaine