// Height and Length

H = 6000;
L = 2000;

// when the refinement of the glide plane starts
ref_glide_start = 750;

// minimum and maximum mesh size

e_min = 0.25;
e_max = 100;

////////////////////////////////////////////////////////
////////////////////////////////////////////////////////
///		          Model Geometry 1			    	 ///
////////////////////////////////////////////////////////
////////////////////////////////////////////////////////

////////////////////////////////////////////////////////
// points

Point(1) = {0,0,0,e_max};
Point(2) = {L, 0, 0, e_max};
Point(3) = {L, H/2, 0, e_max};
Point(4) = {0, H/2, 0, e_max};

Point(5) = {L, H, 0, e_max};
Point(6) = {0, H, 0, e_max};

////////////////////////////////////////////////////////
// Lines

Line(1) = {1,2};
Line(2) = {2,3};
Line(3) = {3,4};
Line(4) = {3,5};
Line(5) = {5,6};
Line(6) = {6,4};
Line(7) = {4,1};

Line Loop(1) = {1,2,3,7};
Line Loop(2) = {-3,4,5,6};


Plane Surface(1) = {1};
Plane Surface(2) = {2};

////////////////////////////////////////////////////////
////////////////////////////////////////////////////////
///	         		 refinements	   		 		 ///
////////////////////////////////////////////////////////
////////////////////////////////////////////////////////

////////////////////////////////////////////////////////
// Intersection point

Point(100) = {L, H/2, 0, e_max};

Field[1] = Attractor;
Field[1].NodesList = {100};

Field[2] = Threshold;
Field[2].IField = 1;
Field[2].LcMin = e_min/2;
Field[2].LcMax = e_max;
Field[2].DistMin = 2;
Field[2].DistMax = 1.5*e_max;

////////////////////////////////////////////////////////
// Glide plane phase A

Point(101) = {ref_glide_start, H/2, 0, e_max};
Line(101) = {101,100};

Field[3] = Attractor;

Field[3].NNodesByEdge = 250;
Field[3].EdgesList = {101};
Field[3].NodesList = {101};

Field[4] = Threshold;
Field[4].IField = 3;
Field[4].LcMin = e_min;
Field[4].LcMax = e_max;
Field[4].DistMin = 3;
Field[4].DistMax = 1.5*e_max;


////////////////////////////////////////////////////////
// Phase boundary

Point(121) = {L, H/2 - 40, 0, e_max};
Point(122) = {L, H/2 + 40, 0, e_max};

Line(121) = {121, 122};

Field[7] = Attractor;
Field[7].NNodesByEdge = 100;
Field[7].EdgesList = {121};
Field[7].NodesList = {121,122};

Field[8] = Threshold;
Field[8].IField = 7;
Field[8].LcMin = e_min;
Field[8].LcMax = e_max;
Field[8].DistMin = 2;
Field[8].DistMax = 1.5*e_max;

Field[9] = Min;
//	Field[9].FieldsList = {2,4,6,8};
	Field[9].FieldsList = {2,4,8};

Background Field = 9;

Mesh.RandomFactor = 1e-9;