[Gmsh] discovered a bug in Gmsh!

[Jean-Francois Remacle <remacle@scorec.rpi.edu>]

Hello,

It seems that your curve 8 is intersected by curves
2 and 4. The geometry is wrong (in our sense).
Gmsh geometries have to be conformal.

Here is a workable version of your geometry :

//-- begin here ----------------------------------------

/* Transmission line setup, first test version
In order to test and train the gmsh and getDP utilities forline impedance
calculations, first amicrostrip line will be tested.
The geometry is 2D
 */

/* Definition of some line parameters for free programming:
  Line Width LW
  Line thickness LT
  metal conductivity cond
  Substrate height SH
  dielectric constant epsr
*/

mum = 1e-6;

LW = 150 * mum;
LT = 10 * mum;
cond = 4.1e7;
SH = 254 * mum;
epsr = 8.6;

// defining points of the geometry

// Conductor
Point(1) =  {-LW , SH, 0, 1 * mum};
Point(2) =  { LW , SH, 0, 1 * mum};
Point(3) =  {LW , SH+LT, 0, 1 * mum};
Point(4) =  {-LW , SH+LT, 0, 1 * mum};

// Plane calc
Point(5) = {-10*LW, 0, 0, 140 * mum};
Point(6) = {-10*LW, 10*SH, 0, 140 * mum};
Point(7) = { 10*LW, 10*SH, 0, 140 * mum};
Point(8) = { 10*LW, 0, 0, 140 * mum};

// Substrate Calc
Point(9) = {-10*LW, SH,0,140 * mum};
Point(10) = {10*LW, SH,0,140 * mum};

// Connecting the points to lines
Line(1) = {5,9};
Line(2) = {9,6};
Line(3) = {6,7};
Line(4) = {7,10};
Line(5) = {10,8};
Line(6) = {8,5};
Line(7) = {1,4};
Line(8) = {4,3};
Line(9) = {3,2};
Line(10) = {2,1};
Line(11) = {1,9};
Line(12) = {2,10};
Line Loop(13) = {2,3,4,-12,-9,-8,-7,11};
Plane Surface(14) = {13};
Line Loop(15) = {7,8,9,10};
Plane Surface(16) = {15};
Line Loop(17) = {-1,-6,-5,-12,10,11};
Plane Surface(18) = {17};
Physical Surface (1) = {14}; // conductor
Physical Surface (2) = {16}; // plane
Physical Surface (3) = {17}; // substrate
//------------- ends here --------------------------
JF

--
Jean-Francois Remacle, Research Associate
Scientific Computation Research Center     (518) 276-8045
Rensselaer Polytechnic Insitute
http://www.scorec.rpi.edu/~remacle
CII
110 8th Street
Troy, New York 12180-3590


On Mon, 25 Mar 2002, Michael Raum wrote:

> Hello,
>
> I got the following message (see attached file) after meshing the geometry (see attached file). Well, it was my first trial with gmsh, but the basic problem and the message do not look like a usage error.
>
> Best regards <<microstrip-line.geo>>  <<.gmsh-errors>>
> ______________________________________
> Dr. Michael Raum
>
> CoreOptics GmbH
> Advanced Transponder Technology
> Nordostpark 12-14
> D-90411 Nürnberg, Germany
>
> *  Phone: +49-911-94151 744
> * Fax:     +49-911-4808682
> * E-mail: <mailto:michaelr at coreoptics.com>
> ______________________________________
>
>