# [Gmsh] structured mesh in wedge.

Christophe Geuzaine christophe.geuzaine at case.edu
Wed Jun 21 15:56:21 CEST 2006

```mark starnes wrote:
> Hi everyone.  I've spent a couple of days trying to crack this one and
> now have to admit to needing help.  I have a wedge I'd like to mesh
> using a structured mesh.  Following example 6,  I defined my lines with
> the same directions, my surfaces with the same normals, my transfinite
> surfaces with the same topology order and my transfinite volume with the
> same topology order.  The surface elements are displayed but the 3D
> elements will not generate.  If somebody can let me know what I'm doing
> wrong, I'd appreciate it.

Hi Mark - You're just missing the actual volume definition:

// Gmsh project created on Wed Jun 21 09:44:15 2006
Point(1) = {-1,0,-1,0.1};
Point(2) = { 1,-1,-1,0.1};
Point(3) = { 1,1,-1,0.1};
Point(4) = {-1,0,1,0.1};
Point(5) = { 1,-1,1,0.1};
Point(6) = { 1,1,1,0.1};
Line(1) = {1,2};
Line(2) = {1,3};
Line(3) = {2,3};
Line(4) = {1,4};
Line(5) = {4,5};
Line(6) = {2,5};
Line(7) = {3,6};
Line(8) = {5,6};
Line(9) = {4,6};
Line Loop(10) = {5,-6,-1,4};
Ruled Surface(11) = {10};
Line Loop(12) = {-9,7,2,-4};
Ruled Surface(13) = {12};
Line Loop(14) = {-6,-8,7,3};
Plane Surface(15) = {14};

Line Loop(16) = {8,-9,5};
Plane Surface(17) = {16};

Line Loop(18) = {1,3,-2};
Plane Surface(19) = {18};

Surface Loop(20) = {17,15,-11,-19,-13};
Volume(21) = {20};

Transfinite Line {9,5,8,2,1,3,4,6,7} = 4 Using Progression 1;
Transfinite Surface {11} = {1,2,5,4};
Transfinite Surface {13} = {1,3,6,4};
Transfinite Surface {15} = {3,2,5,6};
Transfinite Surface {19} = {1,2,3};
Transfinite Surface {17} = {4,5,6};
Recombine Surface {11,13,15,19,17};

Transfinite Volume{21} = {1,2,3,4,5,6};

Take care,

Christophe

PS: it's probably simpler to define this mesh by extrusion.

>
> Regards,
>
> Mark Starnes.
>
> // Gmsh project created on Wed Jun 21 09:44:15 2006
> Point(1) = {-1,0,-1,0.1};
> Point(2) = { 1,-1,-1,0.1};
> Point(3) = { 1,1,-1,0.1};
> Point(4) = {-1,0,1,0.1};
> Point(5) = { 1,-1,1,0.1};
> Point(6) = { 1,1,1,0.1};
> Line(1) = {1,2};
> Line(2) = {1,3};
> Line(3) = {2,3};
> Line(4) = {1,4};
> Line(5) = {4,5};
> Line(6) = {2,5};
> Line(7) = {3,6};
> Line(8) = {5,6};
> Line(9) = {4,6};
> Line Loop(10) = {5,-6,-1,4};
> Ruled Surface(11) = {10};
> Line Loop(12) = {-9,7,2,-4};
> Ruled Surface(13) = {12};
> Line Loop(14) = {-6,-8,7,3};
> Plane Surface(15) = {14};
>
> Line Loop(16) = {8,-9,5};
> Plane Surface(17) = {16};
>
> Line Loop(18) = {1,3,-2};
> Plane Surface(19) = {18};
> Transfinite Line {9,5,8,2,1,3,4,6,7} = 4 Using Progression 1;
> Transfinite Surface {11} = {1,2,5,4};
> Transfinite Surface {13} = {1,3,6,4};
> Transfinite Surface {15} = {3,2,5,6};
> Transfinite Surface {19} = {1,2,3};
> Transfinite Surface {17} = {4,5,6};
> Transfinite Volume{1} = {1,2,3,4,5,6};
> Recombine Surface {11,13,15,19,17};
>
>>
>>
>
> _______________________________________________
> gmsh mailing list
> gmsh at geuz.org
> http://www.geuz.org/mailman/listinfo/gmsh
>

--
Christophe Geuzaine
Assistant Professor, Case Western Reserve University, Mathematics
http://www.case.edu/artsci/math/geuzaine

```