[Gmsh] problem with gmsh 3D

[Christophe Geuzaine]

MENESGUEN Yves 200289 wrote:
> Hello,
> I am a new gmsh user and I need some help to mesh my parallelepiped. I 
> need to mesh this volume to use with freefem3D. The structure I want to 
> mesh is in the joined file. It is made of 5 thin parallelepipeds I need 
> to mesh with ~10 points each one in the z-direction (the thinner) and 40 
> in the x direction and 80 points in the y-direction.
> Gmsh doesn't manage to mesh anything, and I don't understand what the 
> fourth coordinate of the point do.

The fourth coordinate specifies the size of the elements around that 
point (the "characteristic length"). With your choice, you would 
generate billions of elements.

Your geometry should probably be created (and meshed) by extrusion:

lc = 50;
N = 5;

Point(1) = {0,0,290,lc};
Point(2) = {400,0,290,lc};
Point(3) = {400,1000,290,lc};
Point(4) = {0,1000,290,lc};
Line(1) = {1,2};
Line(2) = {2,3};
Line(3) = {3,4};
Line(4) = {4,1};
Line Loop(1) = {1,2,3,4};
Plane Surface(2) = {1};

tmp1[] = Extrude{0,0, 300 - 290}{ Surface{2}; Layers{N}; };
tmp2[] = Extrude{0,0, 300.3 - 300}{ Surface{tmp1[0]}; Layers{N}; };
tmp3[] = Extrude{0,0, 305.6586 - 300.3}{ Surface{tmp2[0]}; Layers{N}; };
tmp4[] = Extrude{0,0, 305.9028 - 305.6586}{ Surface{tmp3[0]}; Layers{N}; };
tmp5[] = Extrude{0,0, 308.9995 - 305.9028}{ Surface{tmp4[0]}; Layers{N}; };

Physical Volume(63) = {tmp1[1], tmp2[1], tmp3[1], tmp4[1], tmp5[1] };


For more info please read the tutorials and the doc, where all these 
concepts are explained.

Christophe






>  
> Best regards,
>  
> -----------------------------------------------
> *Yves Ménesguen*
> Post-doctorant
> /Laboratoire National Henri Becquerel/
> /CEA Saclay/
> /91191 Gif-sur-Yvette Cedex/
> Email : yves.menesguen at cea.fr <mailto:yves.menesguen at cea.fr>
> Tel : (33) 1 69 08 93 79
> Fax : (33) 1 69 08 26 19
>  
> 
> 
> ------------------------------------------------------------------------
> 
> _______________________________________________
> gmsh mailing list
> gmsh at geuz.org
> http://www.geuz.org/mailman/listinfo/gmsh


-- 
Prof. Christophe Geuzaine
University of Liege, Electrical Engineering and Computer Science
http://www.montefiore.ulg.ac.be/~geuzaine