[Gmsh] Uniform mesh on L-shape domain which contains a arc of circle

[Ruth V. Sabariego]

Hi Mohamed,
Try adding this at the end of your file:

n1 = 14;
Transfinite Line{1,6} = n1 ;

n5 = 11 ;
Transfinite Line{9,10,11} = n5 ;
Transfinite Line{3,4} = Floor[n5/2]+1 ;
Transfinite Surface{15}={3, 5, 9, 10};

n3 = 15;
n2 = 11;
Transfinite Line{2,5} = n2 ;
Transfinite Line{7,8} = Floor[((n5-1)*3 + 2*(n2-1))/2]+1 ;
Transfinite Surface{13}={1,2,6,7};

Recombine Surface '*' ;
Mesh.Smoothing = 10;

Have a look at tutorial t6.geo and doc for explanation: 
http://geuz.org/gmsh/doc/texinfo/gmsh.html#t6_002egeo

Regards,
Ruth







On 17 Feb 2013, at 12:32, mohamed mbehou <mbehoumoh at yahoo.fr> wrote:

> Dear,
> I am a PhD student at the University of Pretoria and working on finite element, and I am a new user of GMSH.
> Please how can I get the uniform mesh on the domain (Plan Surface(13)) and the refine one in the arc of circle (Plan Surface(15)). The domain is defined below. I tried the transfinite, it can't work.
> Your help will be very useful for me. 
> 
> (SEE THE FILE BELOW)
> 
> Best regards,
> 
> MBEHOU Mohamed
> 
> Dpt of Mathematics and Applied Mathematics,
> Faculty of Natural and Agriculture Sciences
> University of Pretoria, South Africa
> Phone (+27) (0) 7 36 55 04 87
> mbehoumoh at gmail.com/mbehoumoh at uy1.uninet.cm
> 
> // Gmsh project created on Sun Feb 17 11:15:46 2013
> h=11;
> lc=1/h;
> Point(1) = {0, 0, 0, lc};
> Point(2) = {0.5, 0, 0, lc};
> Point(3) = {0.5, 0.3, 0, lc};
> Point(4) = {0.5, 0.5, 0, lc};
> Point(5) = {0.7, 0.5, 0, lc};
> Point(6) = {1, 0.5, 0, lc};
> Point(7) = {1, 1, 0, lc};
> Point(8) = {0, 1, 0, lc};
> Point(9) = {0.5, .7, 0, lc};
> Point(10)= {0.3, 0.5, 0, lc};
> Line(1) = {1, 2};
> Line(2) = {2, 3};
> Line(3) = {3, 4};
> Line(4) = {4, 5};
> Line(5) = {5, 6};
> Line(6) = {6, 7};
> Line(7) = {7, 8};
> Line(8) = {8, 1};
> Circle(9) = {5, 4, 9};
> Circle(10) = {9, 4, 10};
> Circle(11) = {10, 4, 3};
> Line Loop(12) = {1, 2, -11, -10, -9, 5, 6, 7, 8};
> Plane Surface(13) = {12};
> Line Loop(14) = {3, 4, 9, 10, 11};
> Plane Surface(15) = {14};
> //Transfinite Surface{15}={3, 4, 5};
>  
> MBEHOU Mohamed
> 
> Dpt of Mathematics,
> Faculty of Sciences, University of Yaounde I, 
> Cameroon. phone: (237) 75 51 82 66
> current address: 
> Dpt of Mathematics and Applied Mathematics,
> Faculty of Natural and Agriculture Sciences
> University of Pretoria, South Africa
> Phone (+27) (0) 7 36 55 04 87
> mbehoumoh at gmail.com/mbehoumoh at uy1.uninet.cm
> _______________________________________________
> gmsh mailing list
> gmsh at geuz.org
> http://www.geuz.org/mailman/listinfo/gmsh

—
Dr. Ir. Ruth V. Sabariego
University of Liege, Electrical Engineering and Computer Science
http://ace.montefiore.ulg.ac.be/







-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://www.geuz.org/pipermail/gmsh/attachments/20130217/9c96b718/attachment.html>